#version 300 es
precision highp float;

// these are our textures
uniform sampler2D msdf;

uniform vec4 fontColor;
uniform vec2 unitRange;

// this comes from the vertex shader
in vec2 texCoordVarying;
out vec4 outputColor;

float median(float r, float g, float b) {
    return max(min(r, g), min(max(r, g), b));
}

float screenPxRange() {
    //ivec2 ts = textureSize(msdf, 0);
    //vec2 unitRange = vec2(pxRange)/vec2(ts);
    vec2 screenTexSize = vec2(1.0)/fwidth(texCoordVarying);
    return max(0.5*dot(unitRange, screenTexSize), 1.0);
}

void main()
{
    vec4 bgColor = vec4(fontColor.rgb,0.0);
    vec4 fgColor = fontColor;

    vec3 msdf_rgb = texture(msdf, texCoordVarying).rgb;
    float sd = median(msdf_rgb.r, msdf_rgb.g, msdf_rgb.b);
    float screenPxDistance = screenPxRange()*(sd - 0.5);
    float opacity = clamp(screenPxDistance + 0.5, 0.0, 1.0);

    if (opacity < 0.5)
        discard;
    outputColor = mix(bgColor, fgColor, opacity);

    //outputColor = vec4(opacity, 1.0-opacity, 0.0, 1.0);
    //outputColor = vec4(1.0-msdf_rgb.rgb, 1.0);
    //outputColor = vec4(1.0,0.0,1.0,1.0);
}
